TTGO LORA32 OLED V1

Last Updated on 15. October 2026 by Suffocation●Link status: OK

Ich habe diese LoRa-Boards vor einiger Zeit im Doppelpack erworben und in der Schublade vergessen. Da nun immer mehr Berichte zum Thema LoRa (Long Range Radio) zu finden sind, wollte ich es auch mal ausprobieren. Meine Versuche habe ich hier dokumentiert.

Es gibt mittlerweile eine Version 2 des Boards. Die Version 2 hat zusätzlich einen AN-Schalter. Hieran kann man die beiden Versionen ganz gut unterscheiden.

Facts

• ESP32
• Display SSD1306
• LoRa Chip SX1276
• 2 Taster – Reset und Prog
• Antenna connection for LoRa antennas
• Just 2x 1.5 mm Lipo connector
• Charging LED red.
• Micro USB CP2100x
• Metal antenna for WiFi
• Fits on breadboard (1 row free on each side)

SX1276 LoRa Chip

Spanish	SX1276
GPIO 19	Miso
GPIO 27	MOSI
GPIO 5	SCK
GPIO 18	Computer Science
GPIO 26	IRQ
GPIO 14	RST

SSD1306 OLED Display

The I2C address is 0x3C.

Spanish	Display
GPIO 4	Seventh-day Adventist
GPIO 15	SCL
GPIO 16	RST

Areas of application

• Remote maintenance
• Sensor nodes

Views

Programming

Libraries

SSD1306

Graphics library

https://github.com/ThingPulse/esp8266-oled-ssd1306●Link status: OK

SX1276

Lora by Sandeep Mistry

https://github.com/sandeepmistry/arduino-LoRa●Link status: OK

Test programme

TTGO liefert ein paar Beispiele, unter anderem einen Sender und einen Empfänger. Die beiden folgenden Programme sind Modifikationen davon.

Sender

Source code OLED_LoRa_Sender.ino (GitHub●Link status: OK)

#include <SPI.h>
#include <LoRa.h>
#include <Wire.h>
#include "SSD1306.h"
#include "images.h"
#include "OledTable.h"

#define SCK     5    // GPIO5  -- SX1278's SCK
#define MISO    19   // GPIO19 -- SX1278's MISO
#define MOSI    27   // GPIO27 -- SX1278's MOSI
#define SS      18   // GPIO18 -- SX1278's CS
#define RST     14   // GPIO14 -- SX1278's RESET
#define DI0     26   // GPIO26 -- SX1278's IRQ(Interrupt Request)
#define BAND    433E6

unsigned int counter = 0;

#define DISPLAY_SDA 4
#define DISPLAY_SCL 15
#define DISPLAY_RST 16
#define SSD_ADDRESS 0x3c

SSD1306 display(SSD_ADDRESS, DISPLAY_SDA, DISPLAY_SCL);
OledTable table(&display,2,2);

String rssi = "--";
String packSize = "--";
String packet ;

int lineCount = 1;
int lineHeight =0;//=  display.getHeight()/lineCount;
int colSize = 0 ; //display.getWidth()/2;


void setup() {

  // Init display 
  pinMode(DISPLAY_RST,OUTPUT);
  digitalWrite(DISPLAY_RST, LOW);    // set GPIO16 low to reset OLED
  delay(50); 
  digitalWrite(DISPLAY_RST, HIGH); // while OLED is running, must set GPIO16 in high、
  display.init();
  display.flipScreenVertically();  
  display.setTextAlignment(TEXT_ALIGN_LEFT);
  display.setFont(ArialMT_Plain_10);
  
  // init table
  table.init();

  pinMode(25, OUTPUT);
  Serial.begin(9600);
  while (!Serial);
  Serial.println();
  Serial.println("LoRa Sender Test");

  SPI.begin(SCK, MISO, MOSI, SS);
  LoRa.setPins(SS, RST, DI0);
  if (!LoRa.begin(433E6)) {
    Serial.println("Starting LoRa failed!");
    while (1);
  }
  //LoRa.onReceive(cbk);
  //  LoRa.receive();
  Serial.println("init ok");
  delay(1500);
}

void loop() {
  table.clear();
  table.setText(0,0, "Sending packet: ");
  table.setText(0,1, String(counter));
  table.refresh();

  // send packet
  LoRa.beginPacket();
  LoRa.print("hello ");
  LoRa.print(counter);
  LoRa.endPacket();

  counter++;
  digitalWrite(25, HIGH);   // turn the LED on (HIGH is the voltage level)
  delay(1000);                       // wait for a second
  digitalWrite(25, LOW);    // turn the LED off by making the voltage LOW
  delay(1000);                       // wait for a second
}

Recipient

Source code OLED_LoRa_Receiver.ino (GitHub●Link status: OK)

/**
* LoRa Receiver 
*
* Created by TTGO
* Modified by StefFam https://www.fambach.net
*/

#include "OledTable.h"
#include <SPI.h>
#include <LoRa.h>
#include <Wire.h>  
#include <SSD1306.h>
#include "images.h"

#define SCK     5    // GPIO5  -- SX1278's SCK
#define MISO    19   // GPIO19 -- SX1278's MISO
#define MOSI    27   // GPIO27 -- SX1278's MOSI
#define SS      18   // GPIO18 -- SX1278's CS
#define RST     14   // GPIO14 -- SX1278's RESET
#define DI0     26   // GPIO26 -- SX1278's IRQ(Interrupt Request)
#define BAND    433E6

#define DISPLAY_SDA 4
#define DISPLAY_SCL 15
#define DISPLAY_RST 16
#define SSD_ADDRESS 0x3c

SSD1306 display(SSD_ADDRESS, DISPLAY_SDA, DISPLAY_SCL);
OledTable table(&display,3,2);

String rssi = "--";
String packSize = "--";
String packet ;


int lineCount = 5;
int lineHeight =0;//=  display.getHeight()/lineCount;
int colSize = 0 ; //display.getWidth()/2;


void loraData(){

  table.clear();
  table.setText(0,0,"Rssi");
  table.setText(0,1, String(rssi));
  
  table.setText(1,0 ,"Received ");
  table.setText(1,1 ,String(packSize)+"[bytes]");

  table.setText(2,0 ,"Content");
  table.setText(2,1 ,packet);
  
  table.refresh();
}

void cbk(int packetSize) {
  packet ="";
  packSize = String(packetSize,DEC);
  for (int i = 0; i < packetSize; i++) { packet += (char) LoRa.read(); }
  rssi = "RSSI " + String(LoRa.packetRssi(), DEC) ;
  loraData();
}

void setup() {

  // Init display 
  pinMode(DISPLAY_RST,OUTPUT);
  digitalWrite(DISPLAY_RST, LOW);    // set GPIO16 low to reset OLED
  delay(50); 
  digitalWrite(DISPLAY_RST, HIGH); // while OLED is running, must set GPIO16 in high、
  display.init();
  display.flipScreenVertically();  
  display.setTextAlignment(TEXT_ALIGN_LEFT);
  display.setFont(ArialMT_Plain_10);
  
  // init table
  table.init();
    
  Serial.begin(115200);
  while (!Serial);
  Serial.println();
  Serial.println("LoRa Receiver Callback");
  SPI.begin(SCK,MISO,MOSI,SS);
  LoRa.setPins(SS,RST,DI0);  
  if (!LoRa.begin(433E6)) {
    Serial.println("Starting LoRa failed!");
    while (1);
  }
  //LoRa.onReceive(cbk);
  LoRa.receive();
  Serial.println("init ok");

}

void loop() {
  int packetSize = LoRa.parsePacket();
  if (packetSize) { cbk(packetSize);  }
  delay(10);
}

So sieht’s aus

Problems

Currently none

Miscellaneous

…

Conclusion

Ein nettes Einsteigerkit. Die Informationen waren etwas schwer zu finden, aber es gibt andere Seiten als die des Herstellers, die gute Tipps geben. Die Verbindung per LoRa ist problemlos. Tests bezüglich der Reichweite und Stabilität habe ich nicht durchgeführt.

• October Check 2026 – Neue Mikrocontroller und Boards●Link status: OK 18. October 2026
• Ulanzi TC001 Smart Pixel Clock●Link status: OK 17. October 2026
• ESP32-C3 Seeed Studio XIAO●Link status: OK 6 April 2024
• ESP32-C3 Super Mini Board●Link status: OK 6 April 2024
• ESP8266 Colourful Weather Station AZSMZ V1.8●Link status: OK 10 February 2024
• Preview – LuatOs ESP32-C3 Board●Link status: OK 26 January 2024
• Arduino Nano 33 BLE●Link status: OK 12 January 2024
• ESP32 Bluetooth Gamepad●Link status: OK 4 January 2024
• Arduino Nano 33 IoT●Link status: OK 24 September 2023
• ESP8266/32 WiFi Manager.●Link status: OK 20 September 2023